Rutina para generar lineas de Radio en circunferencias

Buen día a todos. Saludos desde Perú.
En esta oportunidad para ver si alguien puede colaborarme con un LIPS que realice los siguiente:

Que ha partir de una curva, me genere la linea que represente su radio con su respectiva etiqueta.

Agradecido.

Hola.

Espero y en este link encuentres lo que necesitas.


http://www.lee-mac.com/associativecenterlines.html



Saludos

O al menos que sea algo asi lo que estas solicitando :

Código:

(defun c:radio()
(setq os (getvar "osmode"))
(setvar "osmode" 0)
(setq cirRad (getreal "Ingresa Radio del Circulo : "))
(setq cirCen (getpoint "Dale Pick para el centro del Circulo : "))
(setq dimPT (polar cirCen 45 (+ cirRad 0.375)))
(setq quad (polar cirCen 0 cirRad))
(command "circle" cirCen cirRad "")
(command "dimRadius" quad dimPT)
(setvar "osmode" os)
)

Gracias por dedicar tu tiempo Saulo2016, pero en especifico yo tengo el arco y necesito indicar la linea hacia su centro, y colocar su etiqueta. Como en la imagen indicada, yo solamente tengo el arco azul, la aplicacion lisp deberia generar lo de color blanco.

Agradecido.

Hola que tal, usa este lisp y dime si es lo que nesecitabas.

Código:

(defun c:DRO (/ objEnt pt)
  (setvar "cmdecho" 0)
  (setvar "DIMCEN" 0.1)
  (setvar "DIMTMOVE" 1)
  (setvar "DIMATFIT" 0)
  (setvar "DIMTOFL" 0)
  (setvar "DIMTAD" 1)
  (setq objEnt (entsel "\nSelecciona el arco: "))
  (setq pt (osnap (cadr objEnt) "_midp"))
  (vl-cmdf "dimradius" pt "")
  (setvar "cmdecho" 1)
  (princ)
)

"En especifico yo tengo el arco y necesito indicar la linea hacia su centro, y colocar su etiqueta. Como en la imagen indicada, yo solamente tengo el arco azul, la aplicacion lisp deberia generar lo de color blanco" Si no será mucha molestia, por favor.

Este es un ejemplo perfecto para decir lo del maestro Devit
AUTOCAD NO EDITA IMÁGENES
Si conocieramos si se trata de una acotación o simples líneas y textos, pues una premisa resoluble
Si conocieramos la escala de dibujo, textos etc, pues otra parte resoluble
Pues nada, sube un dwg (si puedes con mas de un caso) a dropbox o cualquier nube de la que nos puedas dar una dirección para descargar y con el ejemplo ya se puede apañar uno.

y luego esta la pregunta, ¿ Quieres las dos acotaciones en los extremos o es simple coincidencia ?

Un saludo

Si no te convence .....
Prueba esto que si tienes la altura de texto correcta, a mi me funciona en el 2014 con un ejemplo parecido

Código:

(defun c:par( / tex lin ent r pc p1 pc1 pc2 ang1 ang2)
(defun tex (palabra punto angulo)
(entmake (list
'(0 . "TEXT")
(cons 10 punto)
(cons 40 (getvar "textsize"))
(cons 1 (strcat "R= "palabra))
(cons 50 angulo)
(cons 7 (getvar "TEXTSTYLE"))
'(71 . 0)'(72 . 4)
(cons 11 punto)
 ))
)
(defun lin (p1 p2)
(entmake (list
'(0 . "LINE")
(cons 10 p1)
(cons 11 p2)
 ))
)
(while (progn
 (setq ent (entsel "\nseleccionar arco : "))
 (if ent (= (cdr(assoc 0 (entget (car ent)))) "ARC"))
 )
 (setq ent (entget (car ent))
 r (cdr (assoc 40 ent))
 pc (cdr(assoc 10 ent))
 p1 (polar pc (cdr(assoc 50 ent)) r)
 p2 (polar pc (cdr(assoc 51 ent)) r)
 ang1 (angle pc p1)
 ang2 (angle pc p2)
 pc1 (mapcar '/ (mapcar '+ pc p1)'(2 2))
 pc1 (polar pc1 (+ ang1(/ pi 2))(*(getvar "textsize")1.2))
 pc2 (mapcar '/ (mapcar '+ pc p2)'(2 2))
 pc2 (polar pc2 (+ ang2(/ pi 2))(*(getvar "textsize")1.2))
 )
 (lin pc p1)
 (tex (rtos r 2 2) pc1 ang1)
 (lin pc p2)
 (tex (rtos r 2 2) pc2 ang2)
)
(princ)
)

Si es esto, quedan por ajustar las rotaciones del texto (no es acotación) y alguna otra cosilla como decimales etc

Un saludo

Excelente nolo, era lo que andaba buscando. Agradecido. Aunque sería genial que se ajuste a un tipo de texto, por ejemplo, con propiedad Anotativa, para poder visualizar en diferentes escalas.

Hola cómo están.
No será más fácil y mejor usar el comando de radio DRA