Distancia entre (poli) líneas...

Ir abajo

Distancia entre (poli) líneas...

Mensaje por eliasp el Miér Feb 21, 2018 7:05 pm

Buen día mis estimados.

Luego de muchos asuntos y trabajos, vuelvo al autocad-lisp. Hace mucho tiempo, en el hispacad me ayudaron con un asunto. No recuerdo quien, pero le agradezco. El asunto es que luego de cambio de máquina y muchas situaciones, no encuentro mis rutinas. Entre ellas había una que lo que hacía es:

Selecciona primera línea.... selecciona segunda.... ingresa distancia....

Entonces, me dibujaba una perpendicular con la distancia requerida. Espero haber sido claro y si quien me ayudó en ése tiempo, si aún la tiene, agradeceré me ayude una vez mas.

En resumen es: "Encontrar el punto entre dos líneas que esté separado X metros ..."

Muchas gracias.............

eliasp

Mensajes : 70
Fecha de inscripción : 17/03/2016

Ver perfil de usuario

Volver arriba Ir abajo

Re: Distancia entre (poli) líneas...

Mensaje por bernie67 el Vie Feb 23, 2018 1:48 am

Y por que no usas acotado? sencillamente quitas las lineas de referencias y dejas solo el texto?
La verdad eso fue lo que entendí...
Saludos
Bernardo
avatar
bernie67

Mensajes : 68
Fecha de inscripción : 22/03/2016
Edad : 51
Localización : Bogota DC-Colombia

Ver perfil de usuario

Volver arriba Ir abajo

Re: Distancia entre (poli) líneas...

Mensaje por eliasp el Vie Feb 23, 2018 2:09 am

Ok. creo que está un poco confusa la explicación... a ver si así:

Tengo un par de líneas que convergen a un punto. Se trata de encontrar en que punto la distancia entre esas dos líneas es "X", por ejemplo: Cuando es a un metro, o 1.75....

La verdad es que si es algo confuso, en fin. Gracias por el interés.

eliasp

Mensajes : 70
Fecha de inscripción : 17/03/2016

Ver perfil de usuario

Volver arriba Ir abajo

Re: Distancia entre (poli) líneas...

Mensaje por Dominguez el Vie Feb 23, 2018 1:44 pm

Creo que esta rutina te puede servir,
dibuja una linea de distancia requerida entre dos lineas convergentes.
Código:
 ; Rutina para hacer chaflan, con longitud de éste fija.
 ; José Luis García Galán. 13 Noviembre, 07, www.HISPACAD.com
(vl-load-com)
(defun c:ch_med   (/ l1 l2 p1l1 p2l1 p1l2 p2l2 distmp anglines lado ptsmasalejado)
 (defun   ptsmasalejado (p1 p2 ptchk)
  (if (> (distance p1 ptchk) (distance p2 ptchk))
  p1
  p2
  )
 )
 (setvar "cmdecho" 0)
 (or *medchaflan* (setq *medchaflan* 1.0))
 (if (and (setq l1 (ssget "_:S" '((0 . "LINE"))))
     (setq l2 (ssget "_:S" '((0 . "LINE"))))
     (setq   l1 (ssname l1 0)
      l2 (ssname l2 0)
     )
    )
  (if (not (eq l1 l2))
  (progn
    (setq p1l1 (vlax-curve-getstartpoint l1)
     p2l1 (vlax-curve-getendpoint l1)
    )
    (setq p1l2 (vlax-curve-getstartpoint l2)
     p2l2 (vlax-curve-getendpoint l2)
    )
    (if   (setq pint (inters p1l1 p2l1 p1l2 p2l2 nil))
    (if (and (not (initget 6))
         (not (vl-catch-all-error-p
          (setq distmp (vl-catch-all-apply
              (function getdist)
              (list (strcat "\nIndique Medida del chaflan <" (rtos *medchaflan*) ">: "))
             )
          )
        )
         )
    )
      (progn (if distmp
         (setq *medchaflan* distmp)
       )
       (setq anglines (abs (- (angle pint (ptsmasalejado p1l1 p2l1 pint)) (angle pint (ptsmasalejado p1l2 p2l2 pint)))))
       (setq lado (/ (/ *medchaflan* 2.0) (sin (/ anglines 2))))
       (setvar "chamfera" lado)
       (setvar "chamferb" lado)
       (setvar "chammode" 0)
       (setvar "trimmode" 0);1)
       (vl-cmdf "_.chamfer" l1 l2)
      )
      (alert (vl-catch-all-error-message distmp))
    )
    (alert "Las líneas seleccionadas son paralelas.")
    )
  )
  (alert "Las dos entidades seleccionadas son la misma linea")
  )
  (prompt "\nEntidad designada *No valida*")
 )
 (princ)
)
avatar
Dominguez

Mensajes : 74
Fecha de inscripción : 20/03/2016
Edad : 68
Localización : Zaragoza (España)

Ver perfil de usuario

Volver arriba Ir abajo

Re: Distancia entre (poli) líneas...

Mensaje por eliasp el Vie Feb 23, 2018 5:53 pm

Maestro Domínguez... es justo lo que necesito.

Muchas gracias

Saludos

eliasp

Mensajes : 70
Fecha de inscripción : 17/03/2016

Ver perfil de usuario

Volver arriba Ir abajo

Re: Distancia entre (poli) líneas...

Mensaje por Contenido patrocinado


Contenido patrocinado


Volver arriba Ir abajo

Volver arriba

- Temas similares

 
Permisos de este foro:
No puedes responder a temas en este foro.