Error Load Layers

Hola A todos los Maestros

Aqui estoy con una duda, y es la siguiente.

Tengo este codigo:

Código:

;;;(prompt "\nDebes Teclear LOADLAYERS para ejecutar, luego elije el grupo de LAYERS para cargar...")

;------------------------------------------------------------------------------------------------------------------
; *** START MAIN FUNCTION ***
;------------------------------------------------------------------------------------------------------------------

(defun c:LOADLAYERS ()
;;; Load the dcl file
(setq dcl_id (load_dialog "LOADLAYERS.dcl"))
   ;;; Load the dialog definition if it is not already loaded
   (if (not (new_dialog "LOADLAYERS" dcl_id))
       (progn
 (alert "The LOADLAYERS.DCL file could not be loaded!")
 (exit)
       )
   )


;; If an action event occurs, do this function
 (action_tile "but1" "(doButton 1)")
 (action_tile "but2" "(doButton 2)")
 (action_tile "but3" "(doButton 3)")
 (action_tile "but4" "(doButton 4)")
 (action_tile "but5" "(doButton 5)")
 (action_tile "but6" "(doButton 6)")
 (action_tile "but7" "(doButton 7)")
 (action_tile "but8" "(doButton 8)")
 (action_tile "but9" "(doButton 9)")
 (action_tile "but10" "(doButton 10)")

 (action_tile "cancel" "(done_dialog)") ;; If an action event occurs, do this function
 (start_dialog) ;; Display the dialog box
 (unload_dialog dcl_id) ;; Unload the dialog box
   (princ)
);defun
(princ)


(defun doButton(a)
  (cond
    ((= a 1) (GENR)        (alert "Todos los LAYERS GENERALES se han cargado correctamente!"))
    ((= a 2) (MECANICO)    (alert "Todos los LAYERS MECANICOS se han cargado correctamente!"))
    ((= a 3) (CIVIL)        (alert "Todos los LAYERS CIVILES se han cargado correctamente!"))
    ((= a 4) (ELECTRICO)    (alert "Todos los LAYERS ELECTRICOS se han cargado correctamente!"))
    ((= a 5) (NEW)        (alert "Todos los LAYERS NEW se han cargado correctamente!"))
    ((= a 6) (EXISTING)    (alert "Todos los LAYERS EXISTING se han cargado correctamente!"))
    ((= a 7) (FUTURE)    (alert "Todos los LAYERS FUTURE se han cargado correctamente!"))

    ((= a 8) (GENR)(MECANICO)(CIVIL)(ELECTRICO) (NEW) (EXISTING) (FUTURE) (alert "Todos los LAYERS se han cargado correctamente!"))

   )
)


;------------------------------------------------------------------------------------------------------------------
; *** PROCESS ALL LAYERS ***
;------------------------------------------------------------------------------------------------------------------

(defun ProcessLayers (/ doc LayerCollection)

(vl-load-com)

; SETQ "DOC" TO THE ACTIVE DOCUMENT.
(setq doc (vla-get-ActiveDocument (vlax-get-Acad-Object)
  )
)

; GET THE "LAYER COLLECTION".
(setq LayerCollection (vla-Get-Layers doc))

; CREATE ALL LAYERS AND ASSIGN COLOR, LINETYPE AND DESCRIPTION.
(mapcar '(lambda (x)
 (setq NewLayer (vla-add LayerCollection (nth 0 x))) ; CREATE A NEW LAYER.
 (vla-put-color NewLayer (nth 1 x)) ; ADD A COLOR TO THE LAYER.
    (if (not (tblobjname "ltype" (nth 2 x))) ; IF LINETYPE DOESN'T EXIST, LOAD IT.
 (vla-load (vla-Get-Linetypes doc) (nth 2 x) "acadiso.lin") ; (STANDARD 'METRIC' ACAD LINETYPES)
    ); _end if
 (vla-put-linetype NewLayer (nth 2 x)) ; ADD A LINETYPE TO THE LAYER.
         (vla-put-Description NewLayer (nth 3 x)) ; ADD A DESCRIPTION TO THE LAYER.
 ); _end lambda

LayerList ; LAYER LIST.
); _end mapcar

); _end defun, ProcessLayers


;-------------------------------------------
;    *** LAYERS GENERALES ***
;-------------------------------------------

;------------------------------------------------------------------------------------------------------------------
; *** LAYERS GENERALES ***
;------------------------------------------------------------------------------------------------------------------

(defun GENR (/ LayerList)
(setvar "cmdecho" 0)

; LAYER NAME:         COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 ("Defpoints"            6 "CONTINUOUS" "Layer General para no imprimir trazos")
 ("DIMENSION"            6 "CONTINUOUS" "Uso General de Cotas")
 ("BORDER"                7 "CONTINUOUS" "Marco Oficial y Textos fijos del Marco")
 ("HATCH"                7 "CONTINUOUS" "Sombreado")
 ("BOM"                1 "CONTINUOUS" "Texto de Lista de Materiales de tamaño 1.6, 2.0, 2.5")
 ("TEXT"                1 "CONTINUOUS" "Textos Generales de tamaño 1.6, 2.0, 2.5")
 ("PRELIMINARY"            1 "CONTINUOUS" "Sello Preliminar")
 ("TITLE"                3 "CONTINUOUS" "Textos de Titulos de 4.0 Para etiquetas como PLANTA, ELEVACION, CORTE")
 ("OFFICIAL_LEGENDS"        5 "CONTINUOUS" "Area Limite de Leyendas Oficiales")
 ("KEY_PLAN"            5 "CONTINUOUS" "Area Limite de Planta Localizacion")
 ("CONTRACTOR"          7 "CONTINUOUS" "Area Para Sello de Contratista")
 ("CONFIDENTIAL_SEAL"       7 "CONTINUOUS" "Leyenda de Confidencialidad")
 ("NORTH"              7 "CONTINUOUS" "Simbolo de NORTE")
 ("SEALS"              7 "CONTINUOUS" "Sellos de Aprobado para Cosntruccion, Revisado con comentarios, etc.")
 ("VIEWPORT"            7 "CONTINUOUS" "Layer para Viewport de Impresion")
 ("ATT_HIDDEN"          1 "CONTINUOUS" "Este Layer no debera ser modificado")
 ("CENTER"              1 "CENTER2"    "Este Layer es para lineas de Centros")
 ("SOLDADURA"          1 "CONTINUOUS" "Layer para dibujar todo lo referente a soldaduras")
 ("OCULTO"              1 "HIDDEN2"    "Layer para dibujar lineas y objetos ocultos")

 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, GENR


;------------------------------------------------------------------------------------------------------------------
; *** LAYERS MECANICOS ***
;------------------------------------------------------------------------------------------------------------------

(defun MECANICO (/ LayerList)
(setvar "cmdecho" 0)

;  LAYER NAME:               COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 ("M_EQUIPMENT"                3 "CONTINUOUS" "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en verde continua")
 ("M_EXISTING_EQUIPMENT"    9 "CONTINUOUS" "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en gris continua")
 ("M_FUTURE_EQUIPMENT"        9 "PHANTOM"    "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en gris fantasma")
 ("M_BUILDING"                6 "CONTINUOUS" "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris continua")
 ("M_EXISTING_BUILDING"        9 "CONTINUOUS" "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris continua")
 ("M_FUTURE_BUILDING"        9 "PHANTOM"    "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris fantasma")
 ("M_STEEL_STRUCTURE"        7 "CONTINUOUS" "Estructuras de acero nuevas como escaleras, plataformas, rejillas, soportería, ductería, detalles, etc. en blanco continua.")
 ("M_EXISTING_STEEL_STRUCTURE" 9 "CONTINUOUS" "Estructuras de acero existentes como: escaleras, plataformas, rejillas, soportería, ductería, detalles etc. en gris continua.")
 ("M_FUTURE_STEEL_STRUCTURE" 9 "PHANTOM"    "Estructuras de acero futuras como: escaleras, plataformas, rejillas, soportería, ductería, detalles etc. en gris fantasma.")
 ("M_REFERENCE_GEOMETRY"    6 "CENTER2"    "Geometría utilizada como información de referencia para el mismo dibujo: ejes, líneas de centro, etc. en magenta centros.")
 ("M_LEVELS"                6 "CONTINUOUS" "Layer para representar curvas de nivel en arreglos generales. El color asignado será magenta y tipo de línea continua.")
 ("M_DUCTS_CHUTES"            3 "CONTINUOUS" "Contiene las geometrías de ductos de desempolve y chutes proyectados. El color asignado será verde y tipo de línea continua.")
 ("M_EXISTING_DUCTS_CHUTES"    9 "CONTINUOUS" "Contiene las geometrías de ductos de desempolve y chutes existentes. El color asignado será gris y tipo de línea continua.")
 ("M_FUTURE_DUCTS_CHUTES"    9 "PHANTOM"    "Contiene las geometrías de ductos de desempolve y chutes futuros. El color asignado será gris y tipo de línea fantasma.")
 ("M_PIPES"                    3 "CONTINUOUS" "Contiene las geometrías de tuberías de proceso proyectadas. El color asignado será verde y tipo de línea continua.")
 ("M_EXISTING_PIPES"        9 "CONTINUOUS" "Contiene las geometrías de tuberías de proceso existentes. El color asignado será gris y tipo de línea continua.")
 ("M_FUTURE_PIPES"            9 "PHANTOM"    "Contiene las geometrías de tuberías de proceso futuras. El color asignado será gris y tipo de línea fantasma.")
 ("M_FLOW_LINES"            5 "CONTINUOUS" "Involucra flujo de material y/o algún fluído usado particularmente en diagramas de flujo. en azul continua.")
 ("M_EXISTING_FLOW_LINES"    9 "CONTINUOUS" "Involucra flujo de material y/o algún fluído existente, usado particularmente en diagramas de flujo. en gris continua.")
 ("M_FUTURE_FLOW_LINES"         9 "PHANTOM"    "Involucra flujo de material y/o algún fluído futuro, usado particularmente en diagramas de flujo. en gris fantasma.")
 ("M_EQUIPMENT_OUT_SERVICE"     9 "PHANTOM"    "Layer para indicar equipos fuera de servicio. en gris fantasma.")
 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, MECANICO


;------------------------------------------------------------------------------------------------------------------
; *** LAYERS CIVILES ***
;------------------------------------------------------------------------------------------------------------------

(defun CIVIL (/ LayerList)
(setvar "cmdecho" 0)

;  LAYER NAME:              COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 ("C_EQUIPMENT"                  3 "CONTINUOUS" "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en verde continua")
 ("C_EXISTING_EQUIPMENT"      9 "CONTINUOUS" "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en gris continua")
 ("C_FUTURE_EQUIPMENT"          9 "PHANTOM"    "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en gris fantasma")
 ("C_BUILDING"                  6 "CONTINUOUS" "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris continua")
 ("C_EXISTING_BUILDING"          9 "CONTINUOUS" "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris continua")
 ("C_FUTURE_BUILDING"          9 "PHANTOM"    "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris fantasma")
 ("C_STEEL_STRUCTURE"          7 "CONTINUOUS" "Estructuras de acero nuevas como escaleras, plataformas, rejillas, soportería, ductería, detalles, etc. en blanco continua.")
 ("C_EXISTING_STEEL_STRUCTURE"  9 "CONTINUOUS" "Estructuras de acero existentes como: escaleras, plataformas, rejillas, soportería, ductería, detalles etc. en gris continua.")
 ("C_FUTURE_STEEL_STRUCTURE"  9 "PHANTOM"    "Estructuras de acero futuras como: escaleras, plataformas, rejillas, soportería, ductería, detalles etc. en gris fantasma.")
 ("C_REFERENCE_GEOMETRY"      6 "CENTER2"    "Geometría utilizada como información de referencia para el mismo dibujo: ejes, líneas de centro, etc. en magenta centros.")
 ("C_LEVELS"                  6 "CONTINUOUS" "Layer para representar curvas de nivel en arreglos generales. El color asignado será magenta y tipo de línea continua.")
 ("C_CONCRETE_STRUCTURE"          3 "CONTINUOUS" "Dibujo de detalle de estructuras de concreto proyectadas. El color asignado será verde y tipo de línea continua.")
 ("C_EXISTING_CONCRETE_STRUCTURE" 9 "CONTINUOUS" "Dibujo de detalle de estructuras de concreto existentes. El color asignado será gris y tipo de línea continua.")
 ("C_FUTURE_CONCRETE_STRUCTURE"  9 "PHANTOM"    "Dibujo de detalle de estructuras de concreto futuro. El color asignado será gris y tipo de línea phantom.")
 ("C_WALLS"                      3 "CONTINUOUS" "Representación de muros internos nuevos de edificios. El color asignado será verde y tipo de línea continua.")
 ("C_EXISTING_WALLS"          9 "CONTINUOUS" "Representación de muros internos existentes de edificios. El color asignado será gris y tipo de línea continua.")
 ("C_EXISTING_BARANDILLA"          2 "CONTINUOUS" "Representación de Barandales, Escaleras, etc. Existentes")
 ("C_BARANDILLA"          40 "CONTINUOUS" "Representación de Barandales, Escaleras, etc. Existentes")
 ("C_FUTURE_WALLS"              9 "PHANTOM"    "Representación de muros internos futuros de edificios. El color asignado será gris y tipo de línea phantom.")
 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, CIVIL


;------------------------------------------------------------------------------------------------------------------
; *** LAYERS ELECTRICOS ***
;------------------------------------------------------------------------------------------------------------------

(defun ELECTRICO (/ LayerList)
(setvar "cmdecho" 0)

;  LAYER NAME:      COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 ("E_EQUIPMENT"                3 "CONTINUOUS" "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en verde continua")
 ("E_EXISTING_EQUIPMENT"    9 "CONTINUOUS" "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en gris continua")
 ("E_FUTURE_EQUIPMENT"        9 "PHANTOM"    "ventiladores, bombas, gusanos, elevadores, bandas, equipos princiaples, colectores de polvo, etc. en gris fantasma")
 ("E_BUILDING"                6 "CONTINUOUS" "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris continua")
 ("E_EXISTING_BUILDING"        9 "CONTINUOUS" "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris continua")
 ("E_FUTURE_BUILDING"        9 "PHANTOM"    "Este layer involucra la geometría de un edificio: elevaciones, plantas, secciones y proyeccciones. en gris fantasma")
 ("E_STEEL_STRUCTURE"        7 "CONTINUOUS" "Estructuras de acero nuevas como escaleras, plataformas, rejillas, soportería, ductería, detalles, etc. en blanco continua.")
 ("E_EXISTING_STEEL_STRUCTURE" 9 "CONTINUOUS" "Estructuras de acero existentes como: escaleras, plataformas, rejillas, soportería, ductería, detalles etc. en gris continua.")
 ("E_FUTURE_STEEL_STRUCTURE" 9 "PHANTOM"    "Estructuras de acero futuras como: escaleras, plataformas, rejillas, soportería, ductería, detalles etc. en gris fantasma.")
 ("E_REFERENCE_GEOMETRY"    6 "CENTER2"    "Geometría utilizada como información de referencia para el mismo dibujo: ejes, líneas de centro, etc. en magenta centros.")
 ("E_ACCESSORIES"            3 "CONTINUOUS" "Botoneras, interruptores, actuadores, motores, cajas de conexiones, lámparas, conexiones, etc. EN verde continua.")
 ("E_CABLING_PIPES"            5 "CONTINUOUS" "Incluye cableado de alimentaciones, distribuciones, sistemas de tierras, alumbrado y fuerza. en azul continuo.")
 ("E_CONTROL_INSTRUMENTATION" 3 "CONTINUOUS" "Incluye diagramas I/O de control e instrumentación. El color asignado será verde y tipo de línea continua.")
 ("E_TRAYS"                    3 "CONTINUOUS" "Incluye diagramas I/O de control e instrumentación. El color asignado será verde y tipo de línea continua.")
 ("E_EXISTING_TRAYS"            9 "CONTINUOUS" "Incluye las trayectorias de las charolas existentes de los equipos principales. El color asignado será gris y tipo de línea continuo.")
 ("E_FUTURE_TRAYS"            9 "PHANTOM"    "Incluye las trayectorias de las charolas existentes de los equipos principales. El color asignado será gris y tipo de línea fantasma.")
 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, ELECTRICO



;------------------------------------------------------------------------------------------------------------------
; *** For New equipment: ***
;------------------------------------------------------------------------------------------------------------------

(defun NEW (/ LayerList)
(setvar "cmdecho" 0)

;  LAYER NAME:      COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 ("NEW EQUIPMENT"               173 220 145 "CONTINUOUS" "New equipment   (Cemex light green)")
 ("DEDUSTING DUCT"              253 210 140 "CONTINUOUS" "New Dedusting Ducts")
 ("BIN"                         253 210 140 "CONTINUOUS" "New Bins")
 ("HOPPER"                      253 210 140 "CONTINUOUS" "New Hoppers")
 ("WATER TRANK"                 253 210 140 "CONTINUOUS" "New Water Tanks")
 ("CHUTE"                       253 210 140 "CONTINUOUS" "New Chutes")
 ("METALLIC SILO"               253 210 140 "CONTINUOUS" "New Metallic Silo")
 ("MAINTENANCE AREA"            252 227 000     "CONTINUOUS"    "New Maintenance Area")
 ("EMPTY BAG & PALLETS AREA"    252 227 000     "CONTINUOUS"    "New Empty Bag and PALLETS Area")
 
 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, NEW



;------------------------------------------------------------------------------------------------------------------
; *** For existing equipment: ***
;------------------------------------------------------------------------------------------------------------------

(defun EXISTING (/ LayerList)
(setvar "cmdecho" 0)

;  LAYER NAME:      COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 
 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, EXISTING



;------------------------------------------------------------------------------------------------------------------
; *** For future equipment: ***
;------------------------------------------------------------------------------------------------------------------

(defun FUTURE (/ LayerList)
(setvar "cmdecho" 0)

;  LAYER NAME:      COLOR: LINETYPE: DESCRIPTION:
(setq LayerList '(
 
 )
); end setq

(ProcessLayers); SEND LAYER LIST TO "Processlayers" FUNCTION.

(setvar "cmdecho" 1)
(setvar "clayer" "0")

); _end defun, FUTURE

En todos los Defun donde configuro los Index Color si logro que me los cree en AutoCAD
Pero en el Defun NEW quiero que me configure los True Color y no puedo hacer que me los confirgure





Este es el error




Espero me pueda ayudar alguien.

No has subido el dcl y no se puede probar. De todas maneras, se me ocurre que pruebes algo así:

Código:

(setq LayerList '(
 ("NEW EQUIPMENT"              "173,220,145" "CONTINUOUS" "New equipment  (Cemex light green)")
 ("DEDUSTING DUCT"              "253,210,140" "CONTINUOUS" "New Dedusting Ducts")
 ("BIN"                        "253,210,140" "CONTINUOUS" "New Bins")
 ("HOPPER"                      "253,210,140" "CONTINUOUS" "New Hoppers")
 ("WATER TRANK"                "253,210,140" "CONTINUOUS" "New Water Tanks")
 ("CHUTE"                      "253,210,140" "CONTINUOUS" "New Chutes")
 ("METALLIC SILO"              "253,210,140" "CONTINUOUS" "New Metallic Silo")
 ("MAINTENANCE AREA"            "252,227,000"    "CONTINUOUS"    "New Maintenance Area")
 ("EMPTY BAG & PALLETS AREA"    "252,227,000"    "CONTINUOUS"    "New Empty Bag and PALLETS Area")
 
 
 )
); end setq

Lo cierto es que, aunque la capa tenga un color del tipo que pones tú, si haces un listado de la capa en cuestión, el código 62, que representa el color, aparece con un número entero, de entre 1 y 255. No sé me ocurre nada.

Perdon por mi torpeza....pero tienes razon me faltó enviar el DCL.....aqui lo tienen...

Código:

LOADLAYERS : dialog {
 label = "Layers Estandar C E M E X ";
////////////////////////////////////////////////////////////////////////////////////////////////////////////
   : boxed_column {

 : boxed_column {
 label = "CEMEX";
 : button {
   key = "but1";
   label = "LAYERS &GENERALES";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
 : button {
   key = "but2";
   label = "LAYERS &MECANICOS";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
 : button {
   key = "but3";
   label = "LAYERS    &CIVILES";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
 : button {
   key = "but4";
   label = "LAYERS &ELECTRICOS";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
 : button {
   key = "but5";
   label = "For New equipment:";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
 : button {
   key = "but6";
   label = "For existing equipment:";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
 : button {
   key = "but7";
   label = "For future equipment:";
   is_default = false;
   alignment = centered;
   fixed_width = false;
 }
                                                         : button {
   key = "but8";
   label = "CARGAR TODOS LOS LAYERS";
   is_default = false;
   alignment = centered;
   is_cancel = true;
   fixed_width = false;
 }

 
 } //end : boxed_column
//////////////////////////////////////////////////////////////////////////////////////////////////////////////
 : boxed_row {
                    label = "";
                          : column {

 : button {
   key = "cancel";
   label = "&Cerrar";
   alignment = centered;
   is_default = true;
   is_cancel = true;
   fixed_width = true;
 }

  } //end : column

                            } //fin : boxed_column

/////////////////////////////////////////////////////////////////////////////////////////////////////////////
    } //end : boxed_row

        } //end : dialog

Buenas. He cambiado la función NEW por esta otra:

Código:

(defun NEW (/ LayerList)
  (vl-load-com)

  ; SETQ "DOC" TO THE ACTIVE DOCUMENT.
  (setq doc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
  (setvar "cmdecho" 0)

  ;  LAYER NAME:      COLOR ACI; Color verdadero: LINETYPE: DESCRIPTION:
  ;(setq lista_capa (tblsearch "layer" "Lineas"))
  (setq LayerList '(
    ("NEW EQUIPMENT"               81 11394193 "CONTINUOUS" "New equipment   (Cemex light green)")
    ("DEDUSTING DUCT"              41 16634508 "CONTINUOUS" "New Dedusting Ducts")
    ("BIN"                         41 16634508 "CONTINUOUS" "New Bins")
    ("HOPPER"                      41 16634508 "CONTINUOUS" "New Hoppers")
    ("WATER TRANK"                 41 16634508 "CONTINUOUS" "New Water Tanks")
    ("CHUTE"                       41 16634508 "CONTINUOUS" "New Chutes")
    ("METALLIC SILO"               41 16634508 "CONTINUOUS" "New Metallic Silo")
    ("MAINTENANCE AREA"            2 16573184     "CONTINUOUS"    "New Maintenance Area")
    ("EMPTY BAG & PALLETS AREA"    2 16573184     "CONTINUOUS"    "New Empty Bag and PALLETS Area")
 
 
    )
  ); end setq
  (setq n 0)
    (foreach elem LayerList
      (if (null (tblobjname "LAYER" (car elem)))
        (entmake (list
 '(0 . "LAYER")
 '(100 . "AcDbSymbolTableRecord")
 '(100 . "AcDbLayerTableRecord")
 (cons 2 (car elem))
 (cons 62 (nth 1 elem))
 (cons 420 (nth 2 elem))
 (cons 6 (nth 3 elem));tipo de linea
 '(70 . 0)
 
       )
        )
      )
      (setq LayerCollection (vla-Get-Layers doc))
      (setq mi_capa (vla-item LayerCollection (car elem)))
    
      (vla-put-Description mi_capa (nth 4 elem)) ; ADD A DESCRIPTION TO THE LAYER.
      (setq n (1+ n))
    );fin foreach

  (setvar "cmdecho" 1)
  (setvar "clayer" "0")
); _end defun, NEW

Prueba a ver si te funciona.

Hola muy buenas Robierzo

Excelente amigo....no me equivoqué, eres un Master.

Solo una cosa que no entendi...

De donde sale esta combinacion de numeros??....o como los debo interpretar???...es algo nuevo para mi....que significan esos numeros??

Las entidades con colores RGB, además del código dxf 62, que corresponde al color ACI, llevan asociado el código dxf 420, al que corresponde ese número largo, que es el RGB. Si tu dibujas una línea con un color 173,220,145, y obtienes la lista de esa entidad, ya te sale el valor del código 62 y el valor del código 420, para ese color en concreto.
Para las capas es exactamente igual.

Excelente Amigo, muchas gracias por tu apoyo y explicacion.

Pero una ultima pregunta....¿donde consigo o de donde descargo los codigos DXF 60 y 420??

Te pregunto porque mira lo que me arroja el LIST del Autocad cuando listo el objeto Linea lo dibujo con el color 173,220,145, no me dá el valor del codigo 62 ni el valor del codigo 420....y no sé como obtenerlo...





perdon por mi ignorancia por favor.

Mediante entget obtienes la lista de la entidad. Puedes hacerlo desde el editor de Visual Lisp o desde la linea de comandos.
Yo suelo teclear en la linea de coamandos esto:

Código:

(entget(car(entsel)))

Seleccionas la entidad y ya te sale la lista de todos los códigos, incluso el 62 y el 420.

Hola

Sigo sin comprender esto, sé que estoy pecando de ignorante, pero si necesito que me quede bien claro esto.

Con este codigo que me estas compartiendo (que en verdad yo desconocia) y asi como me explicaste hice lo siguiente....dibujé una linea, le cree un layer con el color 173,220,145, corro el codigo, selecciono la entidad y me sale esto:



Y por mas que busco no encuentro el resultado de los codigos DXF 60 y 420....una vez mas pido disculpas con mi insistencia....pero quiero aprender.




Saludos

No, no. Si tu dibujas una línea con color "por capa", esos códigos no aparecen.
Cuando las entidades tienen color "por capa", el código 62 se omite.
Tienes que dibujar una línea y asignarle el color 173,220,145.
Entonces, aplicas (entget(car(entsel))) y verás como sí te aparecen.

Por otra parte, si tu tienes una capa con el color 173,220,145, y quieres saber cual es el código DXF 420, eso sí que no tengo ni idea. Por eso yo me inventé lo de hacerlo a través de una entidad que no sea una tabla de símbolos, como es una capa o un bloque o una presentación..... Esas entidades son tablas de símbolos y es un poco más enrevesado acceder a la base de datos. Pero si haces como te digo, a través de una entidad como una línea, ya lo averiguas sin problema.

Excelente Amigo robierzo, ya pude lograrlo....sabia que tu me ayudarias con esta bronca.

quedo listo....te estoy muy agradecido.



Bueno amigo te debo otra.....muchas gracias!!!