Datos de Cuadro de Construcción

Buen día señores.

Para el tema de los caminos, al eje se le deben obtener algunos datos, por ejemplo: Coordenadas de los puntos inicial y final, cadenamientos, cuando tienen curvas, longitud del arco, cuarda, en fin algunos datos. El punto es que existe un programa llamado Civil Cad que obtiene esos datos y los presenta en forma de cuadro, al se llama "Cuadro de Construcción"
El asunto es que, actualmente las autoridades solicitan toda esa información pero en formato de reporte. Inicialmente, se llenaba el reporte con "copia y pega" Ahora, me puse a hacer un lisp para obtener esos datos en formato SCV, pero con las curvas me he topado, puesto que no supe como obtener los datso de la cuerda y los rumbos.

Anexo un archivo de CAD, donde se muestran dos ejes con sus respectivos cuadros de construcción.

Espero puedan orientarme para obtener los datos que me faltan.

Saludos y gracias

https://www.dropbox.com/s/cfkytlacvz2qmik/Drawing1.dwg?dl=0

Hola Elías

Las polilíneas guardan la curvatura de los segmentos curvos como un "bulge" en el código dxf 42 y echando mano a la generosidad de Lee-mac, que comparte las funciones para obtener radio y centro desde el bulge

Lee-Mac -> Bulge to Arc

Pues aquí está más o menos el cálculo de esos valores. Solo me dio perecilla convertir el delta a grados, por lo que te lo doy en radianes y vos lo formateás.

Código:


;leer datos de la polilinea
(setq pline (car (entsel))
      lent   (entget pline)
      ptos   (mapcar
               'cdr
               (vl-remove-if-not
                  '(lambda (X)
                     (= (car X) 10)
                  )
                  lent
               )
            )
      blgs   (mapcar
               'cdr
               (vl-remove-if-not
                  '(lambda (X)
                     (= (car X) 42)
                  )
                  lent
               )
            )
      k      1
)

;iterar por cada segmento.
(while (cdr ptos)
   ;si es curvo
   (if (not (zerop (car blgs)))
      (progn
         (setq
            p1   (car ptos)
            p2   (cadr ptos)
            ;Datos de arco desde dos puntos y bulge, tomado de la pagina de Lee-Mac
            a   (* 2. (atan (car blgs)))
            r   (/ (distance p1 p2) 2 (sin a))
            c   (polar p1 (+ (- (/ pi 2) a) (angle p1 p2)) r)
            ;valores angulo y radio
            del   (abs (* a 2.))
            rad   (abs r)
         )
         ;Calculo e impresión de datos de curva
         (princ
            (strcat
               "\n--------------------------------------\nCurva entre vértices "
                              (itoa k) " y " (itoa (1+ k)) ":\n"
               "\n\t-Centro:  Norte= " (rtos (cadr c) 2 4) " / Este= " (rtos (car c) 2 4)
               "\n\t-Delta en radianes: "   (rtos del 2 8) " m."
               "\n\t-Radio: "               (rtos rad 2 3) " m."
               "\n\t-Longitud de arco: "   (rtos (* rad del) 2 3) " m."
               "\n\t-Tangente: "            (rtos (* r (/ (sin a)(cos a))) 2 3) " m."
               "\n\t-Cuerda: "            (rtos (distance p1 p2) 2 3) " m."
               "\n\t-Area sector circ.: "   (rtos (* r r (- del (sin del)) 0.5) 2 3) " m."
            )
         )
         (entmake (list '(0 . "LINE") '(62 . 252) (cons 10 p1) (cons 11 c)))
         (entmake (list '(0 . "LINE") '(62 . 252) (cons 10 p2) (cons 11 c)))
      );progn
   )
   (setq ptos   (cdr ptos)
         blgs   (cdr blgs)
         k      (1+ k)
   )
)
(textscr)

Faltaba mas maestro..... esa talacha yo me la echo. Muchas gracias....