INSERT POINT EN CENTRO DE CIRCULOS

Buenas noches con todos, por favor alguien tendrá una rutina que me ayude a poner point a centro de circulos?.
Pasa que estoy terminado un trabajo y en todo mi plano existen mas de 2000 círculos y trato de insertarle un marca con un insert point, pero tengo la opción de hacerlo múltiples pero a la vez seleccionar uno por uno a los círculos en cuestión y que gran trabajo hacerlos para los 2000 círculos.
Por lo tanto saben de alguna rutina que me ayude a insertar los benditos puntos pero masivamente? que seleccione yo mediante una ventana todos los círculos existentes y de un zas me inserte los dichosos puntos (point).
Desde ya las gracias por la respuesta.
Saludos
Carlos.

Código:

(defun C:PTOC (/ cen cnt grp)
  (setq grp (ssget (list (cons 0 "CIRCLE"))) cnt 0)
  (while (> (sslength grp) cnt)
    (setq cen (cdr (assoc 10 (entget (ssname grp cnt)))))
    (entmake
      (list
        '(0 . "POINT")
        '(100 . "AcDbEntity")
        '(67 . 0)
        '(100 . "AcDbPoint")
        (cons 10 cen)
        )
      )
    (setq cnt (1+ cnt))
    )
  (princ)
  )

Un saludo.

Estimado Kasperle; acabo de probar la rutina que pasaste para el tema y corre de maravillas. Se te agradece el detalle, ademas me servirá para aprender un poco lo de lips ya que estuve intentando todos estos días, sin éxito alguno.
Gracias maestro.
Saludos

Carlos

Siempre podrías usar el dataextraction y luego insertar un point en el centro de los círculos...mas trabajoso pero mejor que a mano. Pero ya con rutina que maravilla
saludos
Bernardo

Aqui hay otra rutina para insertar puntos dentro de todos los circulos designados.

Código:

 ; Dibuja un punto en el centro de cada circulo ó arco designado.
 ; Luis dominguez Gómez © 2008
(defun c:pt_cen   (/ osm cir n cant pins lay)
 (setvar "cmdecho" 0)
 (setq lay (getvar "clayer"))
 (setq osm (getvar "osmode"))
 (if (not (tblsearch "layer" "PUNTOS_LDG"))
  (entmake '((0 . "LAYER")
       (100 . "AcDbSymbolTableRecord")
       (100 . "AcDbLayerTableRecord")
       (2 . "PUNTOS_LDG")
       (70 . 0)
       (62 . 151)
       (6 . "CONTINUOUS")
       )
  )
 )
 (setvar "clayer" "puntos_ldg")
 (setq cir (ssget '((-4 . "<OR") (0 . "CIRCLE") (0 . "ARC") (-4 . "OR>"))))
 (setq n 0)
 (repeat (sslength cir) (setq cant (cons (ssname cir n) cant)) (setq n (1+ n)))
 (foreach x cant (command "_point" (setq pins (trans (cdr (assoc 10 (entget x))) 0 1))))
 (setvar "clayer" lay)
 (setvar "osmode" osm)
 (prin1)
)


Saludos

Funciona de maravillas... Gracias (y)

no se olviden de las SETVAR PDSIZE y PDMODE